Hvordan gemmes regnearkdata som csv-fil med / uden dobbelt anførselstegn?

Når du eksporterer eller gemmer en række data fra Excel til csv-fil, er csv-data normalt ikke med dobbelt anførselstegn, men hvis dine celleværdier er adskilt med komma eller linjeskift, vil de eksporterede csv-data være omkring med dobbelt citater. Og denne artikel vil jeg tale om, hvordan man gemmer regnearkdata som csv-fil med eller uden dobbelt anførselstegn, som du har brug for.

Gem regnearkdata som csv-fil med dobbelt anførselstegn

Gem regnearkdata som csv-fil uden dobbelt citater

Gem regnearkdata som csv-fil med dobbelt anførselstegn

For at gemme de normale data som csv-fil med dobbelt anførselstegn, kan følgende VBA-kode hjælpe dig, gør som følger:

1. Hold nede ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

2. Klik indsatte > Moduler, og indsæt følgende kode i Moduler Vindue.

VBA-kode: Gem regnearkdata som csv-fil med dobbelt anførselstegn:

Sub CSVFile()
'updateby Extendoffice
    Dim xRg As Range
    Dim xRow As Range
    Dim xCell As Range
    Dim xStr As String
    Dim xSep As String
    Dim xTxt As String
    Dim xName As Variant
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Please select the data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    xName = Application.GetSaveAsFilename("", "CSV File (*.csv), *.csv")
    xSep = Application.International(xlListSeparator)
    Open xName For Output As #1
    For Each xRow In xRg.Rows
        xStr = ""
        For Each xCell In xRow.Cells
            xStr = xStr & """" & xCell.Value & """" & xSep
        Next
        While Right(xStr, 1) = xSep
            xStr = Left(xStr, Len(xStr) - 1)
        Wend
        Print #1, xStr
    Next
    Close #1
    If Err = 0 Then MsgBox "The file has saved to: " & xName, vbInformation, "Kutools for Excel"
End Sub

3. Og tryk derefter på F5 nøgle til at køre denne kode, og der vises en promptboks for at minde dig om at vælge det dataområde, du vil gemme som csv-fil med dobbelt anførselstegn, se skærmbillede:

4. Klik derefter på OK knappen og a Gem som vindue vises, angiv filnavnet og placeringen, og klik derefter på Gem knap, se skærmbillede:

5. Og a Kutools til Excelpromptboks vises for at minde dig om, at den nye csv-fil er gemt på din angivne placering, se skærmbillede:

6. Klik OK for at lukke dialogen, og nu, når du åbner din nye csv-fil, er alle data omgivet af de dobbelte anførselstegn som vist nedenstående skærmbillede:

Gem regnearkdata som csv-fil uden dobbelt citater

Hvis dine data adskilles med komma, linjeskift i en celle, når du gemmer dataene som csv-fil, vil dataene være omgivet af de dobbelte anførselstegn som vist nedenfor:

For at gemme dataene som csv-fil uden de dobbelte anførselstegn, skal du anvende følgende VBA-kode.

1. Hold nede ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

2. Klik indsatte > Moduler, og indsæt følgende kode i Moduler Vindue.

VBA-kode: Gem regnearkdata som csv-fil uden dobbelt anførselstegn:

Sub Export()
'updateby Extendoffice
    Dim xRg As Range
    Dim xRow As Range
    Dim xCell As Range
    Dim xStr As String
    Dim xTxt As String
    Dim xName As Variant
    On Error Resume Next
    If ActiveWindow.RangeSelection.Count > 1 Then
      xTxt = ActiveWindow.RangeSelection.AddressLocal
    Else
      xTxt = ActiveSheet.UsedRange.AddressLocal
    End If
    Set xRg = Application.InputBox("Please select data range:", "Kutools for Excel", xTxt, , , , , 8)
    If xRg Is Nothing Then Exit Sub
    xName = Application.GetSaveAsFilename("", "CSV File (*.csv), *.csv")
    Open xName For Output As #1
    For Each xRow In xRg.Rows
        xStr = ""
        For Each xCell In xRow.Cells
            xStr = xStr & xCell.Value & Chr(9)
        Next
        While Right(xStr, 1) = Chr(9)
            xStr = Left(xStr, Len(xStr) - 1)
        Wend
        Print #1, xStr
    Next
    Close #1
    If Err = 0 Then MsgBox "The file has saved to: " & xName, vbInformation, "Kutools for Excel"
End Sub

3. Tryk derefter på F5 nøgle til at køre denne kode, og der vises en hurtigboks for at minde dig om at vælge det dataområde, som du vil gemme som csv uden dobbelt anførselstegn, se skærmbillede:

4. Klik OK knappen og a Gem som vindue vises, angiv venligst et filnavn og placering til din nye csv-fil, se skærmbillede:

5. Og klik derefter på Gem knap, a Kutools til Excelpromptboks vises for at fortælle dig, at den nye csv-fil er gemt på din angivne placering, se skærmbillede:

6. Klik OK for at lukke dialogen, og når du åbner din nye csv-fil, fjernes de dobbelte citater omgivet med data som vist på følgende skærmbillede: