Fjern landekoden fra en kontakts telefonnummer

Fjern landekode fra telefonnumre til kontakter med VBA

Hvis du bare skal fjerne landekoden fra et telefonnummer til en kontakt, kan du manuelt slette den som følger:

1. i Mennesker (eller Kontakt os) visning, klik Specifikation > Skift visning > Telefon. Se skærmbillede:

2. Dobbeltklik for at åbne den kontakt, hvis telefonnummer du vil fjerne landnummer fra.

3. Fjern kontakttegnet og landekoden i det åbne kontaktvindue fra den angivne telefon i Telefonnumre sektion, og klik derefter på Kontakt > Gem og luk.

Indtil videre er landekoden fjernet fra det angivne telefonnummer som vist nedenstående skærmbillede:

Hvis du har brug for at fjerne landekoden fra alle telefonnumre på alle kontakter i Outlook, anbefaler jeg en VBA til at håndtere det let.

1. i Mennesker (eller Kontakt os) visning, åbn kontaktmappen, hvor du vil fjerne landekoden fra alle kontakter.

2. Trykke andre + F11 taster samtidigt for at åbne vinduet Microsoft Visual Basic til applikationer.

3. klik indsatte > Moduler, og indsæt derefter under VBA-kode i det nye åbningsmodul-script.

VBA: Fjern landekode fra alle telefonnumre på alle kontakter

Sub FixPhoneFormat()

 Dim oFolder As MAPIFolder
Set oFolder = Application.ActiveExplorer.CurrentFolder

 If Left(UCase(oFolder.DefaultMessageClass), 11) <> "IPM.CONTACT" Then
MsgBox "You need to select a Contacts folder", vbExclamation
Exit Sub
End If

Dim nCounter As Integer
nCounter = 0

Dim oItem
For Each oItem In oFolder.Items
Dim oContact As ContactItem

          If TypeName(oItem) <> "DistListItem" Then
Set oContact = oItem
With oContact
.AssistantTelephoneNumber = FixFormatUSPhone(.AssistantTelephoneNumber)
.Business2TelephoneNumber = FixFormatUSPhone(.Business2TelephoneNumber)
.BusinessFaxNumber = FixFormatUSPhone(.BusinessFaxNumber)
.BusinessTelephoneNumber = FixFormatUSPhone(.BusinessTelephoneNumber)
.CallbackTelephoneNumber = FixFormatUSPhone(.CallbackTelephoneNumber)
.CarTelephoneNumber = FixFormatUSPhone(.CarTelephoneNumber)
.CompanyMainTelephoneNumber = FixFormatUSPhone(.CompanyMainTelephoneNumber)
.Home2TelephoneNumber = FixFormatUSPhone(.Home2TelephoneNumber)
.HomeFaxNumber = FixFormatUSPhone(.HomeFaxNumber)
.HomeTelephoneNumber = FixFormatUSPhone(.HomeTelephoneNumber)
.ISDNNumber = FixFormatUSPhone(.ISDNNumber)
.MobileTelephoneNumber = FixFormatUSPhone(.MobileTelephoneNumber)
.OtherFaxNumber = FixFormatUSPhone(.OtherFaxNumber)
.OtherTelephoneNumber = FixFormatUSPhone(.OtherTelephoneNumber)
.PagerNumber = FixFormatUSPhone(.PagerNumber)
.PrimaryTelephoneNumber = FixFormatUSPhone(.PrimaryTelephoneNumber)
.RadioTelephoneNumber = FixFormatUSPhone(.RadioTelephoneNumber)
.TelexNumber = FixFormatUSPhone(.TelexNumber)
.TTYTDDTelephoneNumber = FixFormatUSPhone(.TTYTDDTelephoneNumber)

.Save

nCounter = nCounter + 1
End With
End If
Next

MsgBox nCounter & " contacts processed.", vbInformation

End Sub

Private Function FixFormatUSPhone(Phone As String) As String

Phone = Trim(Phone)
FixFormatUSPhone = Phone
If Phone = "" Then Exit Function
Dim prefix As String
prefix = Left(Phone, 1)

' Configured for US
' Enter the correct prefix here
Do While (prefix = "+" Or prefix = "1")

' if the prefix is 2 digits, change to 4;
' if 3 digits, change to 5
Phone = Mid(Phone, 3)
prefix = Left(Phone, 1)
Loop

' After we clean up the country code, we remove non-numeric characters
' Can be tweaked to change formatting, ie: change 202.555.1212 to 202-555-1212

 Phone = Replace(Phone, "(", "")
Phone = Replace(Phone, ")", "")
Phone = Replace(Phone, ".", "")
Phone = Replace(Phone, " ", "")
Phone = Replace(Phone, "-", "")

 FixFormatUSPhone = Phone

End Function

4. Trykke F5 eller klik på Run-knap for at køre denne VBA.

5. Og så vises en dialogboks, der viser dig, hvor mange kontakter der er behandlet. Klik på OK knappen for at lukke den.

Nu vil du se landekoden er fjernet fra alle slags telefonnumre fra alle kontakter. Se skærmbillede:

Spor telefonopkald med tidsskrifter i Outlook

Søg efter kontakter efter telefonnummer i Outlook