Hvordan gemmes e-mail-besked som billedformat (jpg / tiff) i Outlook?

Har du nogensinde prøvet at gemme en e-mail-besked som et billede som f.eks. Jpg eller tiff-billede i Outlook? Denne artikel viser dig en metode til løsning af dette problem.

Gem e-mail som billedformat med VBA-kode

Gem e-mail som billedformat med VBA-kode

Gør som følger for at gemme en e-mail-besked som billedformat i Outlook.

1. Vælg en e-mail, du vil gemme som billede, og tryk derefter på andre + F11 taster samtidigt for at åbne Microsoft Visual Basic til applikationer vindue.

2. i Microsoft Visual Basic til applikationer vindue, klik venligst indsatte > Brugerformular. Se skærmbillede:

3. Lave en Brugerform som vist nedenstående skærmbillede.

4. Vælg jpg Mulighed knappen, og skift navn til opbJPG til venstre Ejendomme rude.

5. Gentag ovenstående trin 4 for at omdøbe den anden indstillingsknap til opbTIFF. Og omdøb det OK kommandoknappen og Ophæve kommandoknap som cdbOk , cdb Annuller separat.

Bemærk: Hvis Ejendomme ruden vises ikke i Microsoft Visual Basic til applikationer vindue, skal du klikke på F4 nøgle for at åbne ruden.

6. Dobbeltklik på et tomt mellemrum på brugerformularen for at åbne Kode vindue. Udskift al kode med følgende VBA-script. Og luk derefter vinduet Kode.

VBA-kode 1: Gem e-mail som billede

Option Explicit
'Update by Extendoffice 2018/3/5
Public xRet As Boolean
Private Sub cdbCancel_Click()
  xRet = False
  FrmPicType.Hide
End Sub
Private Sub cdbOk_Click()
  xRet = True
  FrmPicType.Hide
End Sub

7. Vælg Brugerformular1 og skift navn til FrmPicType i Ejendomme rude som vist nedenfor skærmbillede.

8. klik indsatte > Moduler, og kopier derefter nedenstående VBA-kode ind i modulvinduet.

VBA-kode 2: Gem e-mail som billede

Public Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hwnd As Long, ByVal lpOperation As String, ByVal lpFile As String, ByVal lpParameters As String, ByVal lpDirectory As String, ByVal nShowCmd As Long) As Long
'Update by Extendoffice 2018/3/5
Sub ExportEmailAsImage()
Dim xMail As Outlook.MailItem
Dim xFileName, xFilePath, xWdDocPath As String
Dim xPPTApp As PowerPoint.Application
Dim xPresentation As PowerPoint.Presentation
Dim xPPTShape As PowerPoint.Shape
Dim xPicType As String
Dim xFileFormat As PpSaveAsFileType
On Error Resume Next
FrmPicType.Show
If FrmPicType.xRet Then
  If FrmPicType.opbJPG.Value = True Then
    xPicType = ".jpg"
    xFileFormat = ppSaveAsJPG
  ElseIf FrmPicType.opbTIFF.Value = True Then
    xPicType = ".tiff"
    xFileFormat = ppSaveAsTIF
  End If
Else
  Exit Sub
End If
Set xShell = CreateObject("Shell.Application")
Set xFolder = xShell.BrowseForFolder(0, "Select a folder:", 0, 0)
If Not TypeName(xFolder) = "Nothing" Then
    Set xFolderItem = xFolder.self
    xFilePath = xFolderItem.Path & "\"
Else
    xFilePath = ""
    Exit Sub
End If
'ShellExecute 0, "Open", "POWERPNT.exe", "", "", 0
Set xPPTApp = New PowerPoint.Application
xPPTApp.Height = 0
xPPTApp.Width = 0
xPPTApp.WindowState = ppWindowMinimized
xPPTApp.Visible = msoFalse
For Each xMail In Outlook.Application.ActiveExplorer.Selection
    xFileName = Replace(xMail.Subject, "/", " ")
    xFileName = Replace(xFileName, "\", " ")
    xFileName = Replace(xFileName, ":", "")
    xFileName = Replace(xFileName, "?", " ")
    xFileName = Replace(xFileName, Chr(34), " ")
    xWdDocPath = Environ("Temp") & "\" & xFileName & ".doc"
    xMail.SaveAs xWdDocPath, olDoc
    
    Set xPresentation = xPPTApp.Presentations.Add
    xPresentation.Application.WindowState = ppWindowMinimized
    xPresentation.Application.Visible = msoFalse
    With xPresentation
        .PageSetup.SlideHeight = 900 '792
        .PageSetup.SlideWidth = 612
        .Slides.AddSlide 1, .SlideMaster.CustomLayouts(1)
    End With
    xPPTApp.WindowState = ppWindowMinimized
    With xPresentation.Slides(1)
         .Application.Visible = msoFalse
         Set xPPTShape = .Shapes.AddOLEObject(0, 0, 612, 900, , xWdDocPath)
         xPresentation.SaveAs xFilePath & xFileName & xPicType, xFileFormat, msoTrue
    End With
    xPresentation.Close
Next
xPPTApp.Quit
MsgBox "Mails has been successfully saved as picture", vbInformation + vbOKOnly
End Sub

9. klik Værktøjer > Referencer, Tjek Microsoft PowerPoint-objektbibliotek boks og klik derefter på OK knap. Se skærmbillede:

10. Tryk på F5 nøgle for at køre koden. Derefter Brugerformular1 dialogboksen dukker op, vælg venligst en billedtype og klik på OK knap. Se skærmbillede: