Følg nedenstående trin for at kopiere Outlook-mappestruktur til skrivebordet eller Windows Explorer.

1. Klik på navigationsruden for at fremhæve den angivne mappe, hvis mappestruktur du vil kopiere, og tryk på andre + F11 taster for at åbne vinduet Microsoft Visual Basic for Applications.

2. klik Værktøjer > Referencer for at åbne dialogboksen Referencer. Kontroller derefter i dialogboksen Microsoft Scripting Runtime valgmulighed, og klik på knappen OK knap. Se skærmbillede:

3. klik indsatte > Moduler, og kopier og indsæt under VBA-kode i det nye modulvindue.

VBA: Kopier Outlook-mappestruktur til Windows Explorer

Dim xFSO As Scripting.FileSystemObject
Sub CopyOutlookFldStructureToWinExplorer()
    ExportAction "Copy"
End Sub
  
Sub ExportAction(xAction As String)
Dim xFolder As Outlook.Folder
Dim xFldPath As String
xFldPath = SelectAFolder()
If xFldPath = "" Then
    MsgBox "You did not select a folder. Export cancelled.", vbInformation + vbOKOnly, "Kutools for Outlook"
Else
    Set xFSO = New Scripting.FileSystemObject
    Set xFolder = Outlook.Application.ActiveExplorer.CurrentFolder
    ExportOutlookFolder xFolder, xFldPath
End If
Set xFolder = Nothing
Set xFSO = Nothing
End Sub

Sub ExportOutlookFolder(ByVal OutlookFolder As Outlook.Folder, xFldPath As String)
Dim xSubFld As Outlook.Folder
Dim xItem As Object
Dim xPath As String
Dim xFilePath As String
Dim xSubject As String
Dim xCount As Integer
Dim xFilename As String
On Error Resume Next
xPath = xFldPath & "\" & OutlookFolder.Name
'?????????,??????
If Dir(xPath, 16) = Empty Then MkDir xPath
For Each xItem In OutlookFolder.Items
    xSubject = ReplaceInvalidCharacters(xItem.Subject)
    xFilename = xSubject & ".msg"
    xCount = 0
    xFilePath = xPath & "\" & xFilename
    If xFSO.FileExists(xFilePath) Then
        xCount = xCount + 1
        xFilename = xSubject & " (" & xCount & ").msg"
        xFilePath = xPath & "\" & xFilename
    End If
    xItem.SaveAs xFilePath, olMSG
Next
For Each xSubFld In OutlookFolder.Folders
    ExportOutlookFolder xSubFld, xPath
Next
Set OutlookFolder = Nothing
Set xItem = Nothing
End Sub

Function SelectAFolder() As String
Dim xSelFolder As Object
Dim xShell As Object
On Error Resume Next
Set xShell = CreateObject("Shell.Application")
Set xSelFolder = xShell.BrowseForFolder(0, "Select a folder", 0, 0)
If Not TypeName(xSelFolder) = "Nothing" Then
    SelectAFolder = xSelFolder.self.Path
End If
Set xSelFolder = Nothing
Set xShell = Nothing
End Function
  
Function ReplaceInvalidCharacters(Str As String) As String
Dim xRegEx
Set xRegEx = CreateObject("vbscript.regexp")
xRegEx.Global = True
xRegEx.IgnoreCase = False
xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
ReplaceInvalidCharacters = xRegEx.Replace(Str, "")
End Function

4. Trykke F5 eller klik på Kør knap for at køre denne VBA.

5. I dialogboksen Gennemse efter mappe skal du vælge den angivne mappe, du vil placere den kopierede mappestruktur og klikke på OK knap. Se skærmbillede:

Gå nu til den angivne mappe, du vil se mappestrukturen er kopieret til den angivne harddisk. Se skærmbillede:

Bemærk: mappeelementerne, såsom e-mails, aftaler, opgaver osv. kopieres også til tilsvarende mapper på harddisken.

Hvordan kopieres mappestruktur til ny pst-datafil i Outlook?