Hvordan markeres automatisk e-mails baseret på specifik vedhæftet fil i Outlook?

Når du modtager nogle e-mails med en særlig vigtig vedhæftet fil, skal du muligvis markere dem, så du hurtigt og nemt kan finde dem til opstrømning. Denne artikel vil jeg tale om en nem måde til automatisk at markere e-mails, som vedhæftede filer med specifikke navne.

Marker automatisk e-mails baseret på specifik vedhæftet fil med VBA-kode

---

Marker automatisk e-mails baseret på specifik vedhæftet fil med VBA-kode

For automatisk at markere e-mails, der indeholder den specifikke vedhæftede fil, skal du anvende følgende VBA-kode:

1. Start Outlook, og hold derefter nede ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

2. I Microsoft Visual Basic til applikationer dobbeltklik på vinduet Denne OutlookSession fra Project1 (VbaProject.OTM) rude for at åbne en ny tilstand og derefter kopiere og indsætte følgende kode i det tomme modul.

VBA-kode: Flag automatisk e-mails baseret på specifik vedhæftet fil:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    If Item.Class <> olMail Then Exit Sub
    FlagEmail_SpecificAttachments Item
End Sub

Sub FlagEmail_SpecificAttachments(Mail As Outlook.MailItem)
    Dim xAttachment As Outlook.Attachment
    Dim xExt As String
    Dim xFileName As String
    If Mail.Attachments.Count = 0 Then Exit Sub
    For Each xAttachment In Mail.Attachments
        xExt = SplitPath(xAttachment.FileName, 2)
        xFileName = SplitPath(xAttachment.FileName, 1)
        Select Case xExt
            Case "txt", "xlsx", "docx", "pdf"  'Add the file extension as you need
                If InStr(LCase(xFileName), LCase("KTO")) > 0 Then 'Change the text of the attachment name
                    With Mail
                        .ReminderSet = True
                        .ReminderTime = Now + 1
                        .MarkAsTask olMarkTomorrow
                        .Save
                    End With
                End If
        End Select
    Next
End Sub

Public Function SplitPath(FullPath As String, ResultFlag As Integer) As String
Dim xSplitPos As Integer, xDotPos As Integer
xSplitPos = InStrRev(FullPath, "/")
xDotPos = InStrRev(FullPath, ".")
Select Case ResultFlag
    Case 0
        SplitPath = Left(FullPath, xSplitPos - 1)
    Case 1
        If xDotPos = 0 Then xDotPos = Len(FullPath) + 1
        SplitPath = Mid(FullPath, xSplitPos + 1, xDotPos - xSplitPos - 1)
    Case 2
        If xDotPos = 0 Then xDotPos = Len(FullPath)
        SplitPath = Mid(FullPath, xDotPos + 1)
    Case Else
    Err.Raise vbObjectError + 1, "SplitPath Function", "Invalid Parameter!"
End Select
End Function

Bemærk: I ovenstående kode kan du ændre filtypenavnet og vedhæftningsfilnavnet til dit behov.

3. Gem derefter koden, og genstart Outlook for at få koden til at træde i kraft, når du nu modtager de e-mails, som vedhæftnings navne indeholder den angivne tekst, vil Outlook automatisk markere denne e-mail til opfølgning, se skærmbillede: