Hvordan svarer man normalt i mappen med sendte varer fra Outlook? 

Normalt, når du klikker på Svarfunktion i mappen Sendte emner for at sende en yderligere meddelelse til de personer, du har sendt, vises din egen e-mail-adresse i feltet Til som det følgende skærmbillede vises. Dette kan være irriterende for dig at skifte adresse hver gang. Hvordan kunne få Outlook til at bruge den originale modtagers adresse, ikke din?

Svar normalt i mappen Sendte poster fra Outlook med funktionen Svar alle

Svar normalt i mappen Sendte poster fra Outlook med VBA-kode

---

Svar normalt i mappen Sendte poster fra Outlook med funktionen Svar alle

I Outlook er Svar alle funktion kan hjælpe dig med at løse dette problem, skal du gøre som dette:

Når du har brug for at svare på den sendte e-mail til afsendelse igen for at beholde den oprindelige modtagers adresse, skal du klikke Svar alle knappen, og den oprindelige modtagers adresse er placeret på Til felt som følgende skærmbillede vist:

---

Svar normalt i mappen Sendte poster fra Outlook med VBA-kode

Engang glemmer du måske Svar alle funktion, når du besvarer den sendte besked, så nedenstående VBA-kode kan hjælpe dig med at svare normalt i mappen Sendte poster ved hjælp af funktionen Svar. Gør med følgende trin:

1. Hold nede ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

2. I Microsoft Visual Basic til applikationer dobbeltklik på vinduet Denne OutlookSession fra Project1 (VbaProject.OTM) rude for at åbne tilstanden og derefter kopiere og indsætte følgende kode i det tomme modul.

VBA-kode: Svar normalt i mappen Sendte varer fra Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Gem derefter koden, og genstart Outlook for at få kodeeffekten nu, når du klikker på Svar at sende en e-mail igen Sendte ting mappe, vises den originale modtagers adresse i feltet Til, som du har brug for.