Hvordan gemmes kategori, mens du besvarer eller videresender e-mail i Outlook? 

Normalt, når du svarer eller videresender en e-mail, som jeg har kategoriseret, fjernes kategorien automatisk i den sendte e-mail. Hvis du vil beholde kategorien på udgående e-mails i besvarelse eller videresendelse, introducerer denne artikel en metode til at håndtere den.

Behold kategori, mens du besvarer eller videresender e-mail med VBA-kode

---

Behold kategori, mens du besvarer eller videresender e-mail med VBA-kode

1. Hold nede i ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

2. I Microsoft Visual Basic til applikationer dobbeltklik på vinduet Denne OutlookSession fra Project1 (VbaProject.OTM) rude for at åbne tilstanden og derefter kopiere og indsætte følgende kode i det tomme modul.

VBA-kode: Behold kategori, mens du besvarer eller videresender e-mail:

Private WithEvents GExplorer As Outlook.Explorer
Private WithEvents GInspectors As Outlook.Inspectors
Private WithEvents GMailItem As Outlook.MailItem
Private GCategories As String
Private Sub Application_Startup()
    Dim xApp As Outlook.Application
    Set xApp = Outlook.Application
    Set GExplorer = xApp.ActiveExplorer
    Set GInspectors = xApp.Inspectors
End Sub
Private Sub GExplorer_SelectionChange()
    On Error Resume Next
    If TypeName(GExplorer.Selection.Item(1)) <> "MailItem" Then Exit Sub
    Set GMailItem = GExplorer.Selection.Item(1)
    GCategories = GMailItem.Categories
End Sub
Private Sub GInspectors_NewInspector(ByVal Inspector As Inspector)
    On Error Resume Next
    If TypeName(Inspector.CurrentItem) <> "MailItem" Then Exit Sub
   Set GMailItem = Inspector.CurrentItem
    GCategories = GMailItem.Categories
End Sub
Private Sub GMailItem_Forward(ByVal Forward As Object, Cancel As Boolean)
    Call GetCategories(Forward)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GMailItem_ReplyAll(ByVal Response As Object, Cancel As Boolean)
    Call GetCategories(Response)
End Sub
Private Sub GetCategories(ByVal NewMail As Object)
    If NewMail.Class <> olMail Then Exit Sub
    NewMail.Categories = GCategories
End Sub

3. Gem og luk derefter dette kodevindue, luk og genstart Outlook, nu når du svarer eller videresender en e-mail med kategori, bevares kategorien i den udgående besked i Sendte ting, se skærmbillede: