Sådan ryddes alle kategorier fra Outlook?

Antag, der er mange ting, der anvendes til farvekategorien i din Outlook. Hvis du har brug for at rydde alle disse kategorier fra varerne, hvordan kan du håndtere dette job hurtigt og nemt i Outlook?

Ryd alle kategorier fra en bestemt mappe med funktionen Ryd alle kategorier

Ryd alle kategorier fra en bestemt konto med VBA-kode

Ryd alle kategorier fra en bestemt mappe med funktionen Ryd alle kategorier

Hvis du bare har brug for at rydde kategorierne i en bestemt mappe, skal du gøre som dette:

1. Klik på den mappe, du vil fjerne farvekategorierne, og tryk derefter på Ctrl + A for at vælge alle elementerne.

2. Højreklik derefter, og vælg derefter Kategoriser > Ryd alle kategorier fra kontekstmenuen, se skærmbillede:

dok ryd kategori 1

3. Og så er alle farvekategorierne i denne specifikke mappe ryddet på én gang.

Ryd alle kategorier fra en bestemt konto med VBA-kode

For at rydde alle kategorier fra alle emner, såsom e-mails, opgaver, kontakter, noter og så videre fra en konto, kan nedenstående VBA-kode gøre dig en tjeneste:

1. Klik på en konto-e-mail, som du vil rense alle kategorier fra, og hold derefter nede ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

2. Klik indsatte > Moduler, og indsæt følgende makro i Moduler Vindue.

VBA-kode: Ryd alle kategorier fra en bestemt konto:

Sub BatchClearAllCategories_AllOutlookItems()
    Dim xCurrentFolder As Outlook.Folder
    Dim xFolder As Folder, xCurFolder As Folder
    Dim xPos As Integer
    Dim xRootFldName As String
    Set xCurFolder = Outlook.ActiveExplorer.CurrentFolder
    xPos = InStr(3, xCurFolder.FolderPath, "\")
    If xPos > 0 Then
        xRootFldName = Mid(xCurFolder.FolderPath, 3, xPos - 3)
    Else
        xRootFldName = Mid(xCurFolder.FolderPath, 3, Len(xCurFolder.FolderPath) - 2)
    End If
    Set xCurrentFolder = Outlook.Application.Session.Folders(xRootFldName)
    For Each xFolder In xCurrentFolder.Folders
        Call ProcessFolders(xFolder)
    Next
    MsgBox "Clear completed!", vbInformation + vbOKOnly, "Kutools for Outlook"
End Sub
Sub ProcessFolders(ByVal CurFld As Outlook.Folder)
    Dim xItem As Object
    Dim i As Integer
    Dim xSubfolder As Outlook.Folder
    If CurFld.Items.Count > 0 Then
        For i = CurFld.Items.Count To 1 Step -1
            Set xItem = CurFld.Items.Item(i)
            xItem.Categories = ""
            xItem.Save
        Next
    End If
    If CurFld.Folders.Count = 0 Then Exit Sub
    For Each xSubfolder In CurFld.Folders
        Call ProcessFolders(xSubfolder)
    Next
End Sub

3. Tryk derefter på F5 nøgle til at køre det, og derefter poppes en promptboks ud for at minde dig om, at alle kategorier fra den valgte konto er blevet ryddet, se skærmbillede:

dok ryd kategori 2