Hvordan får man afsenderens e-mailadresse fra en eller flere e-mails i Outlook?

Har du nogensinde prøvet at udtrække e-mail-adressen fra feltet "Fra" i en eller flere modtagne e-mails i Outlook? Denne artikel indeholder en VBA-kode, der hjælper dig med at håndtere denne opgave.

Hent afsenderens e-mailadresse fra en eller flere e-mails i Outlook

Kør venligst følgende VBA-kode for at udtrække e-mailadressen fra feltet "Fra" i en eller flere modtagne e-mails i Outlook.

1. Åbn en e-mail-mappe, vælg en e-mail-besked, hvorfra du vil hente afsenderens e-mail-adresse. Tryk på andre + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

Tips: For at vælge flere e-mails skal du holde nede Ctrl og vælg derefter e-mails én efter én.

2. i Microsoft Visual Basic til applikationer vindue, skal du klikke på indsatte > Moduler, og kopier derefter følgende VBA-kode til vinduet Modul (kode).

VBA-kode: Udtræk afsenderens e-mailadresse fra en eller flere e-mails i Outlook

Sub GetSmtpAddressOfSelectionEmail()
  Dim xExplorer As Explorer
  Dim xSelection As Selection
  Dim xItem As Object
  Dim xMail As MailItem
  Dim xAddress As String
  Dim xFldObj As Object
  Dim FilePath As String
  Dim xFSO As Scripting.FileSystemObject
  On Error Resume Next
  Set xExplorer = Application.ActiveExplorer
  Set xSelection = xExplorer.Selection
  For Each xItem In xSelection
    If xItem.Class = olMail Then
      Set xMail = xItem
      xAddress = xAddress & VBA.vbCrLf & "  " & GetSmtpAddress(xMail)
    End If
  Next
  If MsgBox("Sender SMTP Address is: " & xAddress & vbCrLf & vbCrLf & "Do you want to export the address list to a txt file? ", vbYesNo, "Kutools for Outlook") = vbYes Then
    Set xFldObj = CreateObject("Shell.Application").BrowseforFolder(0, "Select a Folder", 0, 16)
    Set xFSO = New Scripting.FileSystemObject
    If xFldObj Is Nothing Then Exit Sub
    FilePath = xFldObj.Items.Item.Path & "\Address.txt"
    Close #1
    Open FilePath For Output As #1
    Print #1, "Sender SMTP Address is: " & xAddress
    Close #1
    Set xFSO = Nothing
    Set xFldObj = Nothing
    MsgBox "Address list has been exported to：" & FilePath, vbOKOnly + vbInformation, "Kutools for Outlook"
  End If
End Sub
Function GetSmtpAddress(Mail As MailItem)
  Dim xNameSpace As Outlook.NameSpace
  Dim xEntryID As String
  Dim xAddressEntry As AddressEntry
  Dim PR_SENT_REPRESENTING_ENTRYID As String
  Dim PR_SMTP_ADDRESS As String
  Dim xExchangeUser As exchangeUser
  On Error Resume Next
  GetSmtpAddress = ""
  Set xNameSpace = Application.Session
  If Mail.sender.Type <> "EX" Then
    GetSmtpAddress = Mail.sender.Address
  Else
    PR_SENT_REPRESENTING_ENTRYID = "http://schemas.microsoft.com/mapi/proptag/0x00410102"
    xEntryID = Mail.PropertyAccessor.BinaryToString(Mail.PropertyAccessor.GetProperty(PR_SENT_REPRESENTING_ENTRYID))
    Set xAddressEntry = xNameSpace.GetAddressEntryFromID(xEntryID)
    If xAddressEntry Is Nothing Then Exit Function
    If xAddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Or xAddressEntry.AddressEntryUserType = olExchangeRemoteUserAddressEntry Then
      Set xExchangeUser = xAddressEntry.GetExchangeUser()
      If xExchangeUser Is Nothing Then Exit Function
      GetSmtpAddress = xExchangeUser.PrimarySmtpAddress
    Else
      PR_SMTP_ADDRESS = "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
      GetSmtpAddress = xAddressEntry.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    End If
  End If
End Function

3. klik Værktøj > Referencer, tjek derefter Microsoft Scripting Runtime boks i Referencer – Projekt 1 dialog boks.

4. Tryk på F5 nøgle for at køre koden. Så a Kutools til Outlook dialogboksen dukker op med en liste over alle afsenderens e-mail-adresser på de valgte e-mails.

Tips:

5. Efter at have klikket på Ja knap, a Gennemse for mappe dialogboksen dukker op. Vælg venligst en mappe for at gemme filen og klik på OK .

6. Endelig a Kutools til Outlook dialogboksen vil poppe op og fortælle dig stien til den eksporterede fil. Klik OK at lukke det.

7. Gå til den mappe, hvor den eksporterede fil er gemt, og åbn den navngivne .txt-fil Adresse for at se afsenderens e-mailadresser på de valgte e-mails.

Kutools til Outlook - bringer 100 avancerede funktioner til Outlook, og gør arbejdet meget nemmere!

• Auto CC / BCC ved regler, når du sender e-mail; Automatisk videresendelse Flere e-mails efter brugerdefineret; Auto svar uden udvekslingsserver og flere automatiske funktioner ...
• BCC Advarsel - vis besked, når du prøver at besvare alle hvis din e-mail-adresse er på BCC-listen; Påmind, når du mangler vedhæftede filer, og mere minder funktioner ...
• Svar (alle) med alle vedhæftede filer i mailsamtalen; Besvar mange e-mails på få sekunder Tilføj automatisk hilsen når svar Tilføj dato til emne ...
• Vedhæftningsværktøjer: Administrer alle vedhæftede filer i alle mails, Automatisk afmontering, Komprimer alle, Omdøb alt, Gem alle ... Hurtig rapport, Tæl valgte mails...
• Kraftige uønskede e-mails efter skik; Fjern duplikerede mails og kontakter... Gør dig i stand til at gøre smartere, hurtigere og bedre i Outlook.

Læs mere ... Hent nu...