Hvordan flytter man automatisk forskellige typer slettede elementer til forskellige mapper i Outlook?

I Outlook vil alle former for slettede emner (mails, opgave, kontakter osv.) blive flyttet til mappen Slettede elementer. Hvis du vil flytte emnerne til forskellige mapper baseret på emnetypen under mappen Slettede emner som vist nedenfor, hvordan kan du lave det i Outlook?

Flyt automatisk forskellige typer slettede elementer til forskellige mapper med VBA-kode

Nedenstående VBA-kode kan hjælpe dig med at flytte de slettede elementer til forskellige mapper automatisk, gør venligst som dette:

1. Start Outlook, og hold derefter nede ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

2. Dobbeltklik derefter Denne OutlookSession fra Projekt-projekt1 rude, og kopier og indsæt derefter nedenstående kode i det tomme kodevindue:

VBA-kode: Flyt automatisk forskellige typer slettede elementer til forskellige mapper

Public WithEvents GDeletedFolder As Outlook.Folder
Public WithEvents GDeletedItems As Outlook.Items
Private Sub Application_Startup()
  Set GDeletedFolder = Application.Session.GetDefaultFolder(olFolderDeletedItems)
  Set GDeletedItems = GDeletedFolder.Items
End Sub
Private Sub GDeletedItems_ItemAdd(ByVal Item As Object)
'Updateby ExtendOffice
Dim xTargetFolder As Outlook.Folder
On Error Resume Next
Select Case TypeName(Item)
  Case "MailItem", "PostItem", "ReportItem", "MeetingItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Mails")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Mails", olFolderInbox)
    End If
  Case "AppointmentItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Appointments")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Appointments", olFolderCalendar)
    End If
  Case "ContactItem", "DistListItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Contacts")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Contacts", olFolderContacts)
    End If
  Case "TaskItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Tasks")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Tasks", olFolderTasks)
    End If
  Case "JournalItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Journals")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Journals", olFolderJournal)
    End If
  Case "NoteItem"
    Set xTargetFolder = GDeletedFolder.Folders("Deleted Notess")
    If xTargetFolder Is Nothing Then
      Set xTargetFolder = GDeletedFolder.Folders.Add("Deleted Notess", olFolderNotes)
    End If
End Select
If xTargetFolder Is Nothing Then Exit Sub
Item.Move xTargetFolder
Set xTargetFolder = Nothing
End Sub

3. Gem derefter denne kode, og genstart Outlook for at aktivere denne kode.

4. Fra nu af, når du sletter et element, vil det blive flyttet til den tilsvarende type mappe under Slettede ting mappen automatisk.

5. For at se resultatet, klik venligst ikonet nederst i mapperuden, og klik derefter på Mapper for at udvide alle mapper i ruden, se skærmbilleder: