Hvordan eksporterer man e-mail-adresser baseret på specifikt domæne i Outlook?

Hvis du vil eksportere e-mailadresserne med et specifikt domæne fra alle kontakter i din Outlook, bedes du læse denne vejledning, som vil hjælpe dig med at anvende en VBA-kode til at udtrække alle e-mailadresserne i et specifikt domæne til en tekstfil som vist nedenfor. .

Eksporter e-mail-adresser baseret på specifikt domæne i Outlook med VBA-kode

For at udtrække alle e-mailadresser med et specifikt domæne fra alle kontakter skal du gøre følgende:

1. Opret en ny tekstfil og giv den et navn, se skærmbillede:

2. Hold nede ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

3. Klik derefter på indsatte > Moduler, og indsæt følgende kode i modulvinduet.

VBA-kode: Eksporter e-mail-adresser baseret på specifikt domæne

Dim GDomain As String
Dim GFileSystem As Object
Dim GFilePath As String
Dim GFileObj As Object
Private Declare PtrSafe Function ShellExecute Lib "shell32.dll" Alias "ShellExecuteA" (ByVal hWnd As Long, _
  ByVal ipOperation As String, ByVal lpFile As String, _
  ByVal lpParameters As String, ByVal lpDirectory As String, _
  ByVal nShowCmd As Long) As Long

Sub ExportListOfEmailAddressesInSpecificDomain()
'Updateby ExtendOffice
Dim xStore As Store
Dim xFolder As Folder
On Error Resume Next
GDomain = InputBox("Enter domain(@***.com):", "Kutools for Outlook")
If Len(GDomain) <> 0 Then
  GFilePath = "C:\Users\skyyang\Desktop\Email Addresses with specific domain.txt" 'Specify the file path
  Set GFileSystem = CreateObject("Scripting.FileSystemObject")
  Set GFileObj = GFileSystem.CreateTextFile(GFilePath, True)
  For Each xStore In Application.Session.Stores
    For Each xFolder In xStore.GetRootFolder.Folders
      If xFolder.DefaultItemType = olContactItem Then
        Call ProcessFolders(xFolder)
      End If
    Next
  Next
  GFileObj.Close
  ShellExecute 0&, vbNullString, GFilePath, vbNullString, vbNullString, 1
End If
End Sub

Sub ProcessFolders(ByVal Fld As Outlook.Folder)
Dim xContactItems As Items
Dim I As Long
Dim xContact As ContactItem
Dim xSubFolder As Folder
On Error Resume Next
Set xContactItems = Fld.Items
For I = xContactItems.Count To 1 Step -1
  If xContactItems(I).Class = olContact Then
    Set xContact = xContactItems(I)
    If InStr(xContact.Email1Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email1Address & vbCrLf)
    ElseIf InStr(xContact.Email2Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email2Address & vbCrLf)
    ElseIf InStr(xContact.Email3Address, GDomain) > 0 Then
      GFileObj.WriteLine (xContact.Email3Address & vbCrLf)
    End If
  End If
Next
If Fld.Folders.Count > 0 Then
  For Each xSubFolder In Fld.Folders
    If xSubFolder.DefaultItemType = olContactItem Then
      Call ProcessFolders(xSubFolder)
    End If
  Next
End If
End Sub

Bemærk: I ovenstående kode skal du ændre filstien "C:\Users\skyyang\Desktop\E-mail-adresser med specifikt domæne.txt" til din egen.

4. Og tryk derefter på F5 nøglen til at køre denne kode. En promptboks er poppet ud, skriv venligst det e-mail-domæne, som du vil eksportere e-mailadresserne baseret på, se skærmbillede: