Outlook: Hvordan fortsætter jeg med at aflyse møde i kalenderen som arrangør?

I Outlook, som mødearrangør, vil mødet automatisk blive slettet fra kalenderen, når du aflyser mødet. I nogle tilfælde vil du måske beholde de aflyste møder i kalenderen for at markere nogle. Der er dog ingen indbyggede funktioner i Outlook, der kan klare dette job. I denne vejledning giver den to VBA-koder til at holde mødet som en aftale, mens du aflyser.

VBA-koder til kopiering af aflyst møde som aftale

VBA-koder til kopiering af aflyst møde som aftale

Her er to koder til at aflyse mødet og kopiere og indsætte det som en aftale på samme tid.

Bemærk: Inden du aktiverer koden, skal du sørge for, at disse to muligheder er markeret:

Aktivér Outlook, klik på File (Felt) > Indstillinger, i vinduet Outlook-indstillinger skal du klikke på Trust Center fane og klik Indstillinger for tillidscenter, og klik derefter i vinduet Trust Center Makroindstillinger fanen, tjek Aktivér alle makroer (anbefales ikke; potentielt farlig kode kan køre) , Anvend makrosikkerhedsindstillinger på installerede tilføjelser muligheder. Klik OK > OK at lukke vinduerne. Genstart Outlook.

1. Skift til Outlook-kalendervisning, og vælg det møde, du vil annullere Tryk på andre + F11 for at aktivere vinduet Microsoft Visual Basic til applikationer.

2. klik indsatte > Moduler for at indsætte et nyt tomt modul. Kopier derefter og indsæt nedenstående kode til den.

Kode: Kopier møde som aftale og aflys det

Sub CopyMeetingAsAppointmentBeforeCancel()
'UpdatebyExtendoffice20221129
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move Application.ActiveExplorer.CurrentFolder
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

3. klik Kør knappen eller tryk på F5 tast, nu er det valgte møde blevet aflyst og en ny aftale med navnet Cancled & subjet.

Hvis du vil kopiere og indsætte mødet som en aftale i en anden kalender og derefter annullere mødet, skal du bruge nedenstående kode:

Kode: Kopier møde som aftale i en anden kalender og aflys det

Sub CopyMeetingAsAppointmentToCalenderBeforeCancel()
'Updatebyextendoffice20221129
Dim xDestCalendar As Outlook.MAPIFolder
Dim xNameSpace As Outlook.NameSpace
Dim xAppointmentItem As AppointmentItem
Dim xMeetingItem As AppointmentItem
On Error Resume Next
Set xNameSpace = Application.GetNamespace("MAPI")
Set xDestCalendar = xNameSpace.PickFolder
If xDestCalendar.DefaultItemType <> olAppointmentItem Then
  MsgBox "Please Select calendar folder. ", vbOKOnly + vbInformation, "Kutools for Outlook"
  Exit Sub
End If
Set xMeetingItem = GetCurrentItem()
Set xAppointmentItem = Application.CreateItem(olAppointmentItem)
With xAppointmentItem
  .Subject = "Canceled: " & xMeetingItem.Subject
  .Start = xMeetingItem.Start
  .Duration = xMeetingItem.Duration
  .Location = xMeetingItem.Location
  .Body = xMeetingItem.Body
  .Save
  .Move xDestCalendar
End With
With xMeetingItem
  .MeetingStatus = olMeetingCanceled
  .Send
  .Delete
End With
Set xDestCalendar = Nothing
Set xNameSpace = Nothing
Set xAppointmentItem = Nothing
Set xMeetingItem = Nothing
End Sub

Function GetCurrentItem() As Object
  On Error Resume Next
  Select Case TypeName(Application.ActiveWindow)
    Case "Explorer"
      Set GetCurrentItem = Application.ActiveExplorer.Selection.Item(1)
    Case "Inspector"
      Set GetCurrentItem = Application.ActiveInspector.CurrentItem
  End Select
End Function

Klik Kør knappen eller tryk på F5 tast, åbnes en dialogboks Vælg mappe, hvor du kan vælge en kalendermappe til at indsætte aftalen på, og klik derefter på OK.