Hvordan fjernes en bestemt type vedhæftede filer fra e-mails i Outlook?

Har du nogensinde prøvet at fjerne vedhæftede filer i flere valgte e-mails efter filtype i Outlook? Såsom at fjerne alle docx- eller png-vedhæftede filer fra valgte e-mails. Hvordan kunne du løse dette job i Outlook?

Fjern specifik type vedhæftede filer fra e-mails med VBA-kode

Fjern specifik type vedhæftede filer fra e-mails med VBA-kode

For at fjerne bestemt type vedhæftede filer fra valgte e-mails kan følgende VBA-kode gøre dig en tjeneste, gør venligst som denne:

1. Vælg de e-mails, du vil fjerne deres specifikke type vedhæftede filer på adresselisten.

2. Hold nede ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

3. Klik derefter på indsatte > Moduler, kopier og indsæt nedenstående kode i det åbnede blanke modul, se skærmbillede:

VBA-kode: Fjern specifik type vedhæftede filer fra e-mails:

Sub DeleteSpecificTypeOfAttachments()
Dim xSelection As Outlook.Selection
Dim xItem As Object
Dim xMailItem As Outlook.MailItem
Dim xAttachment As Outlook.Attachment
Dim xFileType As String
Dim xType As String
Dim xFSO As Scripting.FileSystemObject
Dim I As Integer
On Error Resume Next
Set xSelection = Outlook.Application.ActiveExplorer.Selection
Set xFSO = New Scripting.FileSystemObject
xType = ""
xType = InputBox("Attachment Type:", "Kutools for Outlook", xType, 8)
If Len(Trim(xType)) = 0 Then Exit Sub
For Each xItem In xSelection
    If xItem.Class = olMail Then
        Set xMailItem = xItem
       If xMailItem.Attachments.Count > 0 Then
            For I = xMailItem.Attachments.Count To 1 Step -1
                Set xAttachment = xMailItem.Attachments.Item(I)
                xFileType = xFSO.GetExtensionName(xAttachment.FileName)
                If InStr(xFileType, Trim(xType)) > 0 Then
                    xAttachment.Delete
                End If
            Next I
            xMailItem.Save
        End If
    End If
Next
Set xMailItem = Nothing
Set xFSO = Nothing
End Sub

4. Og så stadig i Microsoft Visual Basic til applikationer vindue, skal du klikke på Værktøjer > Referencer at gå til Referencer-projekt1 dialogboks, og tjek Microsoft Scripting Runtime mulighed fra Tilgængelige referencer listefelt, se skærmbillede:

doc fjern vedhæftning efter type 1

5. Klik derefter på OK for at lukke dialogen skal du nu trykke på F5 nøgle til at køre denne kode, og der vises en hurtigboks, indtast den vedhæftede type, du vil fjerne, se skærmbillede:

doc fjern vedhæftning efter type 2