Hvordan ændres automatisk signatur baseret på modtagere i Outlook?

Forfatter: Siluvia Sidst ændret: 2024-09-13

Som standard har Outlook en indbygget funktion, som brugerne automatisk kan ændre signatur, mens de sender e-mails via forskellige e-mail-konti. Men ud over det vil jeg her vise dig metode til automatisk ændring af signatur baseret på forskellige modtagere i feltet Til i Outlook.

Skift signatur baseret på modtagere automatisk med VBA-kode

Skift signatur baseret på modtagere automatisk med VBA-kode

Følg nedenstående trin for at anvende forskellige signaturer på tilsvarende modtagere, mens du sender e-mails i Outlook.

1. For det første skal du deaktivere den automatisk vedhæftede signaturfunktion i Outlook. Klik venligst File (Felt) > Indstillinger at åbne Outlook Options vindue.

2. i Outlook Options vindue, vælg Post i venstre rude, og klik derefter på Underskrifter knappen i Skriv meddelelser afsnit. Se skærmbillede:

bruge vba til at ændre signatur baseret på modtagere automatisk med kode

3. i Underskrifter og papirvarer dialogboksen, gå til Vælg standardsignatur afsnit under E-mail underskrift fanen skal du vælge en e-mail-konto i Email konto rullelisten, og vælg derefter (Ingen) fra Nye beskeder og Svar / videresend rullelister. Gentag disse trin, indtil alle e-mail-konti er indstillet til (Ingen). Klik derefter på OK .

bruge vba til at ændre signatur baseret på modtagere automatisk med VBA-kode

Bemærk: Du kan også oprette dine nødvendige underskrifter i dette Underskrifter og papirvarer dialog boks.

4. Klik på OK knappen, når den returnerer Outlook Options vindue.

5. Tryk på andre + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

6. i Microsoft Visual Basic til applikationer dobbeltklik på vinduet Denne OutlookSession i venstre rude for at åbne kodevinduet og kopien under VBA-koden ind i vinduet. Se skærmbillede:

VBA-kode: Skift automatisk signatur baseret på modtagere i Outlook

Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
'Updated by ExtendOffice 2022/08/01
Dim xMailItem As MailItem
Dim xRecipients As Recipients
Dim xRecipient As Recipient
Dim xRcpAddress As String
Dim xSignatureFile, xSignaturePath As String
Dim xFSO As Scripting.FileSystemObject
Dim xDoc As Document
Dim xFindStr As String
On Error Resume Next
Set xFSO = New Scripting.FileSystemObject
If Item.Class <> olMail Then Exit Sub
Set xMailItem = Item
Set xRecipients = xMailItem.Recipients
xSignaturePath = CreateObject("WScript.Shell").SpecialFolders(5) + "\Microsoft\Signatures\"
For Each xRecipient In xRecipients
    If xRecipient.AddressEntry.AddressEntryUserType = olExchangeUserAddressEntry Then
        xRcpAddress = xRecipient.AddressEntry.GetExchangeUser.PrimarySmtpAddress
    Else
        xRcpAddress = xRecipient.AddressEntry.Address
    End If
    Select Case xRcpAddress
        Case "Email Address 1"
            xSignatureFile = xSignaturePath & "aaa.htm"
            Exit For
        Case "Email Address 2", "Email Address 3"
            xSignatureFile = xSignaturePath & "bbb.htm"
            Exit For
        Case "Email Address 4"
            xSignatureFile = xSignaturePath & "ccc.htm"
            Exit For
    End Select
Next
VBA.DoEvents
Set xDoc = xMailItem.GetInspector.WordEditor
xFindStr = "From: " & xMailItem.Recipients.Item(1).Name & " <" & xRcpAddress & ">"
If VBA.InStr(1, xMailItem.Body, xFindStr) <> 0 Then
    xDoc.Application.Selection.HomeKey Unit:=wdStory, Extend:=wdMove
    With xDoc.Application.Selection.Find
        .ClearFormatting
        .Text = xFindStr
        .Execute Forward:=True
    End With
    With xDoc.Application.Selection
        .MoveLeft wdCharacter, 2
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
Else
    With xDoc.Application.Selection
        .EndKey Unit:=wdStory, Extend:=wdMove
        .InsertParagraphAfter
        .MoveDown Unit:=wdLine, Count:=1
    End With
End If
xDoc.Application.Selection.InsertFile FileName:=xSignatureFile, Link:=False, Attachment:=False
End Sub

Noter:

1). I VBA-koden skal du erstatte "E-mail-adresse 1/2/3/4" med de bestemte e-mail-adresser på modtagerne.
2). "aaa.htm""bbb.htm"Og"ccc.htm" er de angivne signaturer, du vil sende til de tilsvarende modtagere.
3). I dette tilfælde signatur "aaa" vil blive sendt til "E-mail-adresse 1", signatur"bbb" vil blive sendt til "E-mail-adresse 2"Og"E-mail-adresse 3", og "E-mail-adresse 4" vil modtage e-mailen indlejret med signatur "ccc". Skift dem venligst baseret på dine behov.
4). Hvis der er flere modtagere i en e-mail, tager koden kun den første modtager i betragtning. I dette tilfælde vil andre modtagere modtage e-mails med samme signatur som den første modtager.

7. Klik derefter på Værktøjer > Referencer at gå til Referencer-projekt dialog boks. Kontroller begge i dialogboksen Microsoft Word-objektbibliotek og Microsoft Scripting Runtime indstillinger, og klik derefter på OK knap, se skærmbillede:

8. Tryk på andre + Q taster for at lukke Microsoft Visual Basic til applikationer vindue.

Fra nu af, efter at have skrevet en e-mail og trykket på Send-knappen, indsættes den tilsvarende signatur automatisk i slutningen af e-mail-kroppen baseret på modtagerens e-mail-adresse i feltet Til.

Hvis du vil indsætte tidsstempel som signatur i e-mail-kroppen, mens du opretter / besvarer / videresender ny e-mail i din Outlook, kan du aktivere Tilføj datosignatur, når du opretter en ny, svar og videresend e-mail mulighed for Kutools til Outlook at opnå det. Se skærmbillede:
Download og prøv det nu (30-dages gratis trail)

bruge vba til at ændre signatur baseret på modtagere automatisk med VBA-kode