Hvordan importerer man fødselsdage fra Excel til Outlook-kalender?

Forfatter: Xiaoyang Sidst ændret: 2022-10-19

Hvis du har en lang liste med fødselsdagsoplysninger i et regneark, vil du nu importere disse fødselsdage til din Outlook-kalender som begivenheder. Hvordan kunne du håndtere denne opgave med nogle hurtige metoder?

Importer fødselsdage fra Excel til Outlook-kalender med VBA-kode

Normalt er der ingen direkte måde at importere fødselsdagene til Outlook-kalenderen, her vil jeg oprette en VBA-kode for at løse dette problem, gør venligst med følgende trin:

1. Åbn regnearket, der indeholder de fødselsdage, du vil importere til Outlook, og hold derefter nede ALT + F11 nøgler til at åbne Microsoft Visual Basic til applikationer vindue.

2. Klik indsatte > Moduler, og indsæt følgende kode i modulvinduet.

VBA-kode: Importer fødselsdage til Outlook-kalender

Sub ImportBirthdaysToCalendar()
'Updateby ExtendOffice
Dim xWs As Excel.Worksheet
Dim xRng As Range
Dim xOlApp As Outlook.Application
Dim xCalendarFld As Outlook.Folder
Dim xAppointmentItem As Outlook.AppointmentItem
Dim xRecurrencePattern As Outlook.RecurrencePattern
Dim xRow As Integer
On Error Resume Next
Set xWs = ThisWorkbook.ActiveSheet
Set xRng = Application.InputBox("Please select the data range (only two columns):", "Kutools for Excel", , , , , , 8)
If xRng Is Nothing Then Exit Sub
If xRng.Columns.Count <> 2 Then
  MsgBox "You can only select two columns", vbOKOnly + vbCritical, "Kutools for Excel"
  Exit Sub
End If
Set xOlApp = CreateObject("Outlook.Application")
Set xCalendarFld = xOlApp.Session.GetDefaultFolder(olFolderCalendar)
For xRow = 1 To xRng.Rows.Count
  Set xAppointmentItem = xCalendarFld.Items.Add("IPM.Appointment")
  With xAppointmentItem
    .Subject = xRng.Cells(xRow, 1) & Chr(39) & "s Birthday"
    .AllDayEvent = True
    .Start = xRng.Cells(xRow, 2)
    Set xRecurrencePattern = .GetRecurrencePattern
    xRecurrencePattern.RecurrenceType = olRecursYearly
    .Save
  End With
Next
Set xWs = Nothing
Set xCalendarFld = Nothing
Set xOlApp = Nothing
End Sub

3. Stadig i Microsoft Visual Basic til applikationer vindue, skal du klikke på Værktøjer > Referencer. I sprang ud Referencer - VBAProject dialogboks, tjek Microsoft Outlook 16.0 Objektbibliotek mulighed fra Tilgængelige referencer listefelt, se skærmbillede:

4. Klik derefter på OK for at lukke denne dialogboks. Tryk nu på F5 tasten for at køre denne kode, og en promptboks er poppet ud, vælg venligst navn og fødselsdagskolonner, se skærmbillede:

5. Klik derefter på OK knappen, vil fødselsdagene blive importeret til Outlook-kalenderen på én gang, du kan starte din Outlook for at se resultatet, se skærmbillede: