Excel CHOOSE funktion

Beskrivelse

Syntaks og argumenter

Anvendelse og eksempler

• Ex1 - Grundlæggende brug: brug af CHOOSE funktion alene for at vælge værdi fra listeargument
• Ex2 - Returner forskellige resultater baseret på flere forhold
• Ex3 - Returner forskellige beregnede resultater baseret på forhold
• Ex4 - Vælg tilfældigt fra listen
• Ex5 - Kombiner CHOOSE , VLOOKUP funktioner til at returnere værdi i venstre kolonne
• Ex6 - Returner hverdag eller måned baseret på den givne dato
• Ex7 - Vend tilbage til næste arbejdsdag / weekend dato baseret på i dag

---

Beskrivelse

CHOOSE -funktionen returnerer en værdi fra listen over værdiorgumenter baseret på det givne indeksnummer. For eksempel, CHOOSE(3,”Apple”,”Peach”,”Orange”) returnerer Orange, indeksnummeret er 3, og Orange er den tredje værdi efter indeksnummer i funktionen.

syntaks og argumenter

Formelsyntaks

CHOOSE(index_num, value1, [value2], …)

argumenter

Index_num: Påkrævet. En numerisk værdi mellem 1-254 og indirekte hvilken argumentværdi der vælges. hvis index_num er uden for skalaen mellem 1-254, CHOOSE returnerer #VALUE! fejlværdi. Hvis index_num er en decimalværdi, afrundes den til et helt tal, før formlen bruges. Value1: Påkrævet. Den første værdi i formlen, der kan vælges. Value2: Valgfri. Den anden og op til 254. værdi at vælge imellem.

Value1, value2... kan være tal, tekster, formler, cellereferencer eller defineret navn.

Returværdi

CHOOSE funktion returnerer en værdi fra en liste baseret på den givne position.

Anvendelse og eksempler

I denne del lister jeg nogle enkle, men repræsentative eksempler for at forklare brugen af CHOOSE funktion.

Ex1 - Grundlæggende brug: brug af CHOOSE funktion alene for at vælge værdi fra listeargument

Formel 1:

=CHOOSE(3,"a","b","c","d")

Return: c, som er det tredje argument efter index_num af 3 i CHOOSE funktion.

Bemærk: Brug dobbelt anførselstegn omkring værdien, hvis det er tekst.

Formel 2:

=CHOOSE(2,A1,A2,A3,A4)

Retur: Kate, værdien af ​​A2. Da index_num er 2, og A2 er den anden værdi i CHOOSE funktion.

Formel 3:

=CHOOSE(4,8,9,7,6)

Return: 6, det fjerde listeargument i funktionen.

---

Ex2 - Returner forskellige resultater baseret på flere forhold

Antag at du har en liste over afvigelser for hvert produkt, der skulle mærkes baseret på forhold som vist nedenfor.

Normalt kan du bruge IF-funktionen til at håndtere, men her introducerer jeg, hvordan du bruger CHOOSE funktion til at løse dette problem let

Formel:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

Forklare:

(B7>0)+(B7>1)+(B7>5): index_num, B7 er 2, hvilket er større end 0 og 1, men mindre end 5, så vi får det mellemliggende resultat:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Som vi ved, er True = 1, False = 0, så formlen kan ses som:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

derefter

=CHOOSE(2,"Top","Middle","Bottom")

Resultat: Mellem

---

Ex3 - Returner forskellige beregnede resultater baseret på forhold

Antag at du skal beregne rabatterne for hvert produkt baseret på mængden og prisen som vist nedenstående skærmbillede:

Formel:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

Forklare:

(B8>0)+(B8>100)+(B8>200)+(B8>300): indeksnummer, B8 er 102, hvilket er større end 100, men mindre end 201, så i denne del returnerer det resultatet vist som:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

derefter

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: de værdier, man skal vælge, rabat er lig med pris * beløb * rabatprocent, da her index_num er 2, vælger det B8 * C8 * 0.2

Returnerer: 102 * 2 * 0.2 = 40.8

---

Ex4 - Vælg tilfældigt fra listen

I Excel kan det være nødvendigt, at du tilfældigt vælger en værdi fra en given liste, den CHOOSE funktion kan løse dette job.

Vælg tilfældigt en værdi fra en liste:

Formel:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

Forklare:

RANDBETWEEN(1,5): index_num, få tilfældigt tal mellem 1 og 5

$D$2,$D$3,$D$4,$D$5,$D$6: listen over værdier, hvorfra man kan vælge

---

Ex5 - Kombiner CHOOSE , VLOOKUP funktioner til at returnere værdi i venstre kolonne

Generelt bruger vi VLOOKUP-funktionen =VLOOKUP (value, table, col_index, [range_lookup]) for at returnere en værdi baseret på en given værdi fra et tabelinterval. Men med VLOOKUP funktion, vil den returnere en fejlværdi, mens returkolonnen er til venstre for opslagskolonnen som vist nedenstående skærmbillede:

I dette tilfælde kan du kombinere CHOOSE funktion med VLOOKUP-funktion for at løse problemet.

Formel:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

Forklare:

CHOOSE({1,2},B1:B7,A1:A7): som tabel_range-argument i VLOOKUP-funktionen. {1,2} betyder at vise 1 eller 2 som index_num argument baseret på col_num argumentet i VLOOKUP-funktionen. Her er col_num i VLOOKUP-funktion 2, så den CHOOSE funktionsvisning som CHOOSE(2, B1:B7,A1:A7)betyder at vælge værdi fra A1: A7.

---

Ex6 - Returner hverdag eller måned baseret på den givne dato

Med CHOOSE funktion, kan du også returnere den relative hverdag og måned baseret på en given dato.

Formel 1: returner hverdag efter en dato

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

Forklare:

WEEKDAY(): argumentet index_num, for at få hverdagsnummeret på den givne dato, for eksempel returnerer WEEKDAY (A5) 6, så er index_num argumentet 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": værdilisteargumenter, start med "søndag", fordi hverdagsnummer "1" angiver "søndag".

Formel 2: returmåned efter en dato

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Forklare:

MONTH(): index_num argument, der får månedstallet fra den givne dato, for eksempel returnerer MÅNED (A5) 3.

---

Ex7 - Vend tilbage til næste arbejdsdag / weekend dato baseret på i dag

I det daglige arbejde vil du muligvis beregne den næste hverdag eller weekend baseret på i dag. Her er CHOOSE funktion kan også gøre dig en tjeneste.

For eksempel er i dag 12/20/2018, torsdag, nu skal du hente den næste hverdag og weekend.

Formel 1: få datoen for i dag

=TODAY()

Resultat: 12/20/2018

Formel 2: få antallet af ugedage i dag

=WEEKDAY(TODAY())

Resultat: 5 (mens i dag er 12-20-2018)

Ugedagens nummerliste som vist nedenstående skærmbillede:

Formel 3: få den næste arbejdsdag

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Forklare:

Today(): returner den aktuelle dato

WEEKDAY(TODAY()): index_num argument i CHOOSE funktion, få ugedagstallet i dag, for eksempel søndag er 1, mandag er 2 ...

1,1,1,1,1,3,2: værdi liste argument i CHOOSE fungere. For eksempel, hvis hverdag (i dag ()) returnerer 1 (søndag), vælger den 1 fra listen over værdier, så ændres hele formlen til = I dag () + 1, hvilket betyder at tilføje 1 dag for at vende tilbage næste mandag. Hvis ugedag (i dag ()) returnerer 6 (fredag), vælger den 3 fra listen over værdier, fordi fredag ​​er 3 dage langt fra næste mandag.

Resultat (mens i dag er 12-20-2018):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12/20/2018 + 1

= 12/21/2018

Formel 4: få den næste weekend dag

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

Forklare:

6,5,4,3,2,1,1: værdi liste argument i CHOOSE fungere. For eksempel, hvis hverdag (i dag ()) returnerer 1 (søndag), vælger den 6 fra listen over værdier, så ændres hele formlen til = I dag () + 6, hvilket betyder at tilføje 6 dage og vende tilbage næste lørdag.

Resultat:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12/20/2018 + 2

= 12/22/2018

---

Prøvefil